ionicModel_mod.f90

Go to the documentation of this file.

module ionicmodel_mod

  use choral_variables
  use choral_constants
  use real_type
  use basic_tools
  use br_mod
  use tnnp_mod
 
  implicit none
  private

  !       %----------------------------------------%
  !       |                                        |
  !       |          PUBLIC DATA                   |
  !       |                                        |
  !       %----------------------------------------%
  public :: ionicmodel
  public :: print
  public :: ionicmodel_ilist

  !       %----------------------------------------%
  !       |                                        |
  !       |        ABSTRACT INTERFACES             |
  !       |                                        |
  !       %----------------------------------------%
  abstract interface

     subroutine ionic_term(a, b, I, y, N, Na)
       import :: rp
       real(RP), dimension(Na), intent(out) :: a
       real(RP), dimension(N) , intent(out) :: b
       real(RP)               , intent(in)  :: I
       real(RP), dimension(N) , intent(in)  :: y
       integer                , intent(in)  :: N, Na
     end subroutine ionic_term

  end interface


  !       %----------------------------------------%
  !       |                                        |
  !       |          DERIVED TYPE                  |
  !       |                                        |
  !       %----------------------------------------%

  type ionicmodel
     character(20) :: name

     integer :: type 

     integer :: n

     integer :: na   

     integer :: ni   

     real(RP) :: ist

     real(RP) :: vrest

     ! rest state
     real(RP), dimension(:), allocatable :: y0

     ! model functions
     procedure(ionic_term), nopass, pointer :: ab =>null() 

   contains

     final :: ionicmodel_clear

  end type ionicmodel


  !       %----------------------------------------%
  !       |                                        |
  !       |          GENERIC INTERFACES            |
  !       |                                        |
  !       %----------------------------------------%
  interface print
     module procedure ionicmodel_print
  end interface print

  interface ionicmodel
     module procedure ionicmodel_create
  end interface ionicmodel

  interface clear
     module procedure ionicmodel_clear
  end interface clear

contains


  subroutine ionicmodel_clear(im)
    type(ionicmodel), intent(inout) :: im

    im%type = -1
    im%name = "Undefined"
    im%N    = -1
    im%Na   = -1
    im%NI   = -1

    call freemem(im%Y0)
    im%ab   =>null()

  end subroutine ionicmodel_clear


  function ionicmodel_create(type) result(im)
    type(ionicmodel)    :: im
    integer, intent(in) :: type

    call clear(im)
    im%type  = type

    select case(type)
    case(ionic_br)
       im%name =  "IONIC_BR"
       im%N    =  br_ny
       im%Na   =  br_nw
       im%ab   => br_ab_w
       im%NI   =  br_ni
       im%Ist  =  50.0_rp    ! [A/F]
       call allocmem(im%Y0, im%N)
       call br_y0(im%Y0)
       im%Vrest = im%Y0(im%N)

    case(ionic_br_0)
       im%name =  "IONIC_BR_0"
       im%N    =  br_ny
       im%Na   =  0
       im%ab   => br_ab_0
       im%NI   =  br_ni
       im%Ist  =  50.0_rp    ! [A/F]
       call allocmem(im%Y0, im%N)
       call br_y0(im%Y0)
       im%Vrest = im%Y0(im%N)

    case(ionic_br_wv)
       im%name =  "IONIC_BR_WV"
       im%N    =  br_ny
       im%Na   =  br_ny
       im%ab   => br_ab_wv
       im%NI   =  br_ni
       im%Ist  =  50.0_rp    ! [A/F]
       call allocmem(im%Y0, im%N)
       call br_y0(im%Y0)
       im%Vrest = im%Y0(im%N)

    case(ionic_br_sp)
       im%name =  "IONIC_BR_SP"
       im%N    =  br_ny
       im%Na   =  br_nw
       im%ab   => br_sp_ab_w
       im%NI   =  br_ni
       im%Ist  =  50.0_rp    ! [A/F]
       call allocmem(im%Y0, im%N)
       call br_sp_y0(im%Y0)
       im%Vrest = im%Y0(im%N)

    case(ionic_tnnp)
       im%name =  "IONIC_TNNP"
       im%N    =  17
       im%Na   =  12
       im%ab   => tnnp_ab_w
       im%NI   =  15
       im%Ist  =  52.0_rp    ! [A/F]
       
       call allocmem(im%Y0, im%N)
       call tnnp_y0(im%Y0)
       im%Vrest = im%Y0(im%N)

    case(ionic_tnnp_0)
       im%name =  "IONIC_TNNP_0"
       im%N    =  17
       im%Na   =  12
       im%ab   => tnnp_ab_0
       im%NI   =  15
       im%Ist  =  52.0_rp    ! [A/F]
       
       call allocmem(im%Y0, im%N)
       call tnnp_y0(im%Y0)
       im%Vrest = im%Y0(im%N)

    case default
       call quit(&
         & "ionicModel_mod: ionicModel_create: wrong type")
    end select


    if (choral_verb>0) write (*,*) &
         & 'ionicModel_mod  : create         = ', trim(im%name)

    if (choral_verb>1) write(*,*) &
         & "  Size N, Na                     =", im%N, im%Na

  end function ionicmodel_create


  subroutine ionicmodel_print (im)
    type(ionicmodel) :: im
    
    write(*,*)"ionicModel_mod  : ionicModel_print"
    write(*,*)"  name                           = " // trim(im%name)
    write(*,*)"  N                              =", im%N
    write(*,*)"  NA                             =", im%NA
    write(*,*)"  NI                             =", im%NI
    write(*,*)"  Ist                            =", im%Ist
    write(*,*)"  Vrest                          =", im%Vrest

  end subroutine ionicmodel_print


  subroutine ionicmodel_ilist(I, Y, I_app, type) 
    real(RP), dimension(:), intent(out) :: I
    real(RP), dimension(:), intent(in)  :: Y
    real(RP)              , intent(in)  :: I_app
    integer               , intent(in)  :: type

    select case(type) 
    case(ionic_br, ionic_br_0, ionic_br_wv)
       call br_ilist(i(1:br_ni), y(1:br_ny))

    case(ionic_br_sp)
       call br_sp_ilist(i(1:br_ni), y(1:br_ny))

    case(ionic_tnnp, ionic_tnnp_0)
       call tnnp_ilist(i(1:tnnp_ni), y(1:tnnp_ny))

    case default
       call quit("ionicModel_mod: ionicModel_IList: unknown type")

    end select

  end subroutine ionicmodel_ilist

end module ionicmodel_mod